devis appel d'offres développeur webmaster informatique

RECHERCHE

UN BON

développeur

« L'accès simplifié aux développeurs informatiques et web pour tous vos projets de sites internet, d'applications mobiles, de paramétrages de logiciels et tout autre développement nécessaire à votre entreprise »

LANCER UN APPEL D'OFFRES


Déposez votre projet
GRATUITEMENT et ANONYMEMENT

Recevez TOUTES les propositions
des développeurs intéressés

Transmettez vos coordonnées uniquement à votre SELECTION SHORTLISTEE

Attribuez la mission sur notre site pour
EVALUER LA PRESTATION

DEPOSER UN PROJET

TESTER UN DEVELOPPEUR

idée développeur webmaster société informatique Si vous hésitez à engager un développeur, une petite mission de test peut être la solution, vous avez accès facilement aux sociétés informatiques favorables à ce type d'offres.

TESTEZ MAINTENANT

LES OFFRES DU MOMENT

Rendez-vous sur FaisMonBoulot

DEVELOPPEURS & WEBMASTERS

Nous sommes toujours à la recherche des bons profils de développeurs et webmasters pour répondre aux demandes de nos clients.

Enregistrez-vous sur FAISMONBOULOT.

lundi 10 mars 2014

Importer les contacts Outlook dans Excel avec VBA

outlook contact excel Regrouper tous ses contacts dans une feuille Excel peut s’avérer très utile pour réaliser un publipostage ou un emailing. Cela peut même constituer une première brique pour la création d’un mini-CRM pour piloter sa relation commerciale.

A l’aide d’un code VBA simple, nous allons vous détailler comment importer Nom, Prénom, Adresse Email et Société dans l’onglet actuel d’un classeur Excel.

1ere Etape : Déclaration des Objets et variables

Dim oOutlook As Object 'Application Outlook
Dim namespaceOutlook As Object 'Namespace MAPI
Dim DossierContacts As Object 'Dossier Contacts. Ce dossier est représenté par l'index 10
Dim collectionContacts  As Object 'Collection qui représente l'ensemble  des contacts
Dim itemContact  As Object ‘Représente un contact unique

2eme Etape: Création pour chaque objet d’une instance de celui-ci

Set oOutlook = CreateObject("Outlook.Application") 
Set namespaceOutlook = oOutlook.GetNamespace("MAPI") 
Set DossierContacts = namespaceOutlook.GetDefaultFolder(10) 
Set collectionContacts = DossierContacts.Items

3eme Etape : Boucle sur tous les contacts présents dans Outlook afin de les afficher dans Excel.

L’ensemble des contacts est stocké dans la collection nommée collectionContacts.

For Each itemContact In collectionContacts
        .Cells(iNumLigne, 1) = itemContact.FirstName
        .Cells(iNumLigne, 2) = itemContact.LastName
        .Cells(iNumLigne, 3) = itemContact.Email1Address
        .Cells(iNumLigne, 4) = itemContact.CompanyName
        iNumLigne = iNumLigne + 1 'on passe à la ligne suivante
Next

Code complet de la fonction ExportOutlookContactsDansExcel()

Option Explicit

Sub ExportOutlookContactsDansExcel()

'Déclaration des Objets et variables
Dim oOutlook As Object
Dim namespaceOutlook As Object
Dim DossierContacts As Object
Dim collectionContacts  As Object
Dim itemContact  As Object
'variables
Dim iNumLigne As Long

'Gestion d'erreurs
On Error GoTo Err_Execution

'Création des instances des objets
Set oOutlook = CreateObject("Outlook.Application") 
Set namespaceOutlook = oOutlook.GetNamespace("MAPI") 
Set dossierContacts = namespaceOutlook.GetDefaultFolder(10) 
Set collectionContacts = dossierContacts.Items 

'on indique les libellés des colonnes dans l'onglet Excel
With ActiveSheet
    .Cells(1, 1) = "Nom"
    .Cells(1, 2) = "Prénom"
    .Cells(1, 3) = "Mail"
    .Cells(1, 4) = "Société"
End With

'Boucle sur tous les contacts
iNumLigne = 2 ‘on affiche les données à partir de la deuxième ligne
With ActiveSheet
    For Each itemContact In collectionContacts
        .Cells(iNumLigne, 1) = itemContact.FirstName
        .Cells(iNumLigne, 2) = itemContact.LastName
        .Cells(iNumLigne, 3) = itemContact.Email1Address
        .Cells(iNumLigne, 4) = itemContact.CompanyName
        iNumLigne = iNumLigne + 1 'on passe à la ligne suivante
    Next
End With

'on vide les instances
Set oOutlook = Nothing
Set namespaceOutlook = Nothing
Set dossierContacts = Nothing
Set collectionContacts = Nothing
Set itemContact = Nothing

Fin_Execution:
    Exit Sub
Err_Execution:
    MsgBox Err.Description, vbExclamation + vbOKOnly
    Err.Clear
    Resume Fin_Execution
End Sub

Il ne reste plus qu’à lancer la macro « ExportOutlookContactsDansExcel() » à partir du menu «développeur/macros ».

Cette petite fonction peut facilement être adaptée pour récupérer toute autre information disponible comme le numéro de téléphone ou la fonction de la personne. Pour faciliter l’usage régulier, je vous recommande de créer un bouton sur la barre d’outils voire de lancer cette fonction dès l’ouverture du fichier Excel.

A bientôt pour la prochaine étape des mini-fonctionnalités pour un mini-CRM à développer sous Excel.

Publié par à
Libellés :
Flux RSS